fini
/output,a
/cle
/output

! Testmodel AC R (3D mit SOLID 97 / 117)
! calculate AC resistance 
! massive block with current exictation
! JO 2002
! ANSYS 7.0

! Vergleichsformel ist die Induktivität der Doppelleitung nach Mende / Simon: 
! L/l = my0 / Pi  * ( ln (a/r) +1/4 )    , r ist Drahtradius, a ist Abstand der beiden Drahtmitten.

r=10e-3
lang=1e-3
nstep=20
f_beg=1e-6
f_end=1e3
nl=5		! anzahl Abstaende fuer Luft
a=10*r

rho=1.78e-8

cet=2		!1= 117
		!2= 97

ndf=.75

*dim,resu,table,nstep,4

fini
/config,noeldb,1
/config,norstgeo,1

/prep7
cyl4,a/2,0,0,0,r,360,lang
cyl4,0,0,0,-90,nl*a,90,lang
vovla,1,2
numm,kp

*if,cet,eq,1,then
et,1,117,
et,2,117,1
*else
et,1,97
et,2,97,1
*endif
*if,cet,eq,1,then
et,3,200,7
*else
et,3,200,6
*endif

esiz,ndf*r/6
type,3
ames,1
mat,2
type,2
esiz,,1
vsweep,1

esiz,ndf*2*r
lesi,13,ndf*8*r
lesi,11,ndf*3*r,,,5
lesi,12,ndf*3*r,,,1/5
type,3
ames,10
mshcopy,area,10,11,,,,lang
mat,1
type,1
vsweep,3

acle,all

mp,murx,1,1
mp,murx,2,1
mp,rsvx,2,rho


*if,cet,eq,1,then	! 117
 asel,s,ext
 nsla,s,1
 nsle,r,mid
 d,all,az
 alls
*else			! 97
 cpcy,ax,,0,,,lang
 cpcy,ay,,0,,,lang
 cpcy,az,,0,,,lang
 nsel,s,loc,x,0
 csys,1
 nsel,a,loc,x,nl*a
 d,all,all
 cpdel,all,,,any
 csys
 alls
*endif

asel,s,area,,1
nsla,s,1
nsle,r,corner
cp,1,volt,all
*get,n1,node,,num,min
f,n1,amps,1

asel,s,area,,2
nsla,s,1
nsle,r,corner
d,all,volt,0
alls


/solu
antyp,harm
harf,f_beg,f_end
nsub,nstep
outres,all,all
kbc,1
eqsl,sparse
alls
solve

/post1

*do,jj,1,nstep,1

! Bestimme R und L
! Realteil
set,,jj,1,0
volt1_r=volt(n1)
strom1_r=1
alls

set,,jj,1,1
volt1_i=volt(n1)
strom1_i=0
alls

*get,frq,active,,set,freq 
*afun,rad
pi=acos(-1)
omega=2*pi*frq

sp1_r=(-omega)*(Volt1_i) ! ACTUAL (NOT TIME INTEGRATED) COIL VLTG
sp1_i=(omega)*(Volt1_r) ! ACTUAL (NOT TIME INTEGRATED) COIL VLTG

! R_AC
r_ac=(sp1_r*strom1_r+sp1_i*strom1_i)/(strom1_r**2+strom1_i**2)

! Reactance
rea1=(sp1_i*strom1_r-sp1_r*strom1_i)/(strom1_r**2+strom1_i**2)

! Inductance (self)
l1=rea1/(omega)

! R_DC
ar_c=pi*r**2
r_dc=rho*lang/(ar_c)

! Summary
resu(jj,1)=r_ac
resu(jj,2)=rea1
resu(jj,3)=l1
resu(jj,4)=r_dc
resu(jj,0)=frq

*enddo

! PLOT THIS
/GCOLUMN,1,R_AC
/GCOLUMN,2,L
/axlab,x,Freq [HZ]
/axlab,y,L [H}
/grtyp,2
*vplot,resu(1,0),resu(1,1),3